package prod

import "encoding/yaml"

import "du5t1n.me/cfg/app/promtail/schema"

promtail: {
	scrape: {
		journal: schema.#ScrapeConfig & {
			job_name: "journal"
			journal: {
				labels: {
					job: "systemd-journal"
				}
			}
			relabel_configs: [
				{
					source_labels: ["__journal__hostname"]
					target_label: "hostname"
				},
				{
					source_labels: ["__journal__systemd_unit"]
					target_label: "unit"
				},
				{
					source_labels: ["__journal_syslog_identifier"]
					target_label: "syslog_identifier"
				},
				{
					source_labels: ["__journal_priority"]
					target_label: "priority"
				},
				{
					source_labels: ["__journal_message_id"]
					target_label: "message_id"
				},
				{
					source_labels: ["__journal__comm"]
					target_label: "command"
				},
				{
					source_labels: ["__journal__transport"]
					target_label: "transport"
				},
			]
		}
	}

	ca: """
		-----BEGIN CERTIFICATE-----
		MIIBgTCCATOgAwIBAgIUTf/ZBSJEi8IQb8Ndoxp4/tHB/lcwBQYDK2VwMEAxCzAJ
		BgNVBAYTAlVTMRgwFgYDVQQKDA9EdXN0aW4gQy4gSGF0Y2gxFzAVBgNVBAMMDkRD
		SCBSb290IENBIFIzMB4XDTI0MDIxNzIwMjkzNloXDTM0MDIxNzIwMjkzNlowQDEL
		MAkGA1UEBhMCVVMxGDAWBgNVBAoMD0R1c3RpbiBDLiBIYXRjaDEXMBUGA1UEAwwO
		RENIIFJvb3QgQ0EgUjMwKjAFBgMrZXADIQDORylVcWcxwGDJvsJIc2NctfNfDaIU
		T6mLebahKdshaKM/MD0wHQYDVR0OBBYEFLZoxAHBvWqbLWMga/DAAlG9ido5MA8G
		A1UdEwEB/wQFMAMBAf8wCwYDVR0PBAQDAgEGMAUGAytlcANBANLV79joVd9s9bmL
		0a91HqvOotOnN/416Ek4UTl95jIqy/TvTfRjXX56wSALXqP1iYQM5i3zk3gVEhh4
		DaY+6wQ=
		-----END CERTIFICATE-----
		"""

	config: schema.#PromtailConfig & {
		clients: [
			{
				url: "https://loki.pyrocufflink.blue/loki/api/v1/push"
				tls_config: {
					ca_file: "/etc/promtail/ca.crt"
				}
			},
		]
	}
}

let Marshal = yaml.Marshal

#promtail: {
	#scrape: [...schema.#ScrapeConfig] | *[promtail.scrape.journal]
	ca: string | *promtail.ca

	config: promtail.config & {
		scrape_configs: #scrape
	}

	yaml: Marshal(config)
}